スレッドのキャンセル

      ******************** MAINPROG.CBL ********************
       identification division.
       program-id. mainprog.

       Data Division.
       Local-Storage Section.
       01  ret-ptr                 usage pointer.
       01  iddata-ptr              usage pointer.
       01  sub-iddata-ptr          usage pointer.
       01  sub-handle              usage thread-pointer.
       Linkage Section.
       01  iddata-record.
           05  iddata-name         pic x(20).
           05  iddata-term         pic x comp-x value 0.

       Procedure Division.

      * Establish identification data - don't provide
      * initialization data when it is allocated, instead
      * initialize it after the pointer is retrieved.

           call 'CBL_THREAD_IDDATA_ALLOC' using
                                      by value zero
                                  length of iddata-record
           call 'CBL_THREAD_IDDATA_GET'   using iddata-ptr
                                                omitted
           set address of iddata-record to iddata-ptr
           move 'main' to iddata-name

      * Create sub-thread

      * Starting point
           call 'CBL_THREAD_CREATE' using
                                 'SUBPROG '
                        by value 0   *> No parameters
                                 0   *> Optional - parameter size
                                 0   *> Flag to create detached
                                 0   *> Default priority
                                 0   *> Default stack
                    by reference sub-handle
           if  return-code not = 0
               display 'unable to create thread'
               stop run
           end-if

      * Wait until child creates its iddata and then flag
      * termination

           set sub-iddata-ptr to NULL
           perform until 1 = 0
               call 'CBL_THREAD_IDDATA_GET'
                      using    sub-iddata-ptr
                      by value sub-handle
               end-call
               if  sub-iddata-ptr not = null
                   exit perform
               end-if
               call 'CBL_THREAD_YIELD'
           end-perform
           set address of iddata-record to sub-iddata-ptr
           move "stop" to iddata-name
           move 1 to iddata-term

      * Wait till the child exits
           wait for sub-handle

           display 'All synchronization is complete on ' &
                   'RTS termination'
           stop run.
       end program mainprog.

      *************** SUBPROG.CBL  ********************************
       identification division.
       program-id. subprog.

       Data Division.
       Working-Storage Section.
       01 sub-iddata.
          05  sub-name             pic x(20) value 'sub'.
          05  sub-term             pic x comp-x value 0.
       Local-Storage Section.
       01  iddata-ptr              usage pointer.
       01  thread-handle           usage pointer.
       01  thread-state            pic x(4) comp-x.
       01  parent-handle           usage pointer.
       Linkage Section.
       01  iddata-record.
           05  iddata-name         pic x(20).
           05  iddata-term         pic x comp-x value 0.
       Procedure Division.

      * Establish identification data - provide initialization data
           call 'CBL_THREAD_IDDATA_ALLOC' using
                                        sub-iddata
                               by value length of sub-iddata

      * Find our parent thread and resume him
      *
           call 'CBL_THREAD_LIST_START' using thread-handle
                                              thread-state
                                              iddata-ptr
           set parent-handle to NULL
           perform until thread-handle = null
                      or return-code not = 0
               if iddata-ptr not = null
                   set address of iddata-record to iddata-ptr
                   if  iddata-name = 'main'
                       set parent-handle to thread-handle
                       exit perform
                   end-if
               end-if
               call 'CBL_THREAD_LIST_NEXT' using thread-handle
                                                 thread-state
                                                 iddata-ptr
           end-perform
           call 'CBL_THREAD_LIST_END'
           if  parent-handle = NULL
               display 'synchronization error'
               stop run
           end-if
           call 'CBL_THREAD_IDDATA_GET'   using iddata-ptr
                                                omitted
           set address of iddata-record to iddata-ptr
           perform until iddata-term = 1
               call 'CBL_THREAD_YIELD'
           end-perform
           exit program.
       end program subprog.

この長めのコード例では、実際にはスレッドとアプリケーションの終了について、ハンドシェイクを確立するのみです。これについて説明する前に、主スレッドのハンドルをパラメーターとして子スレッドに渡せば、このようなハンドシェイクの確立をより簡単に行えることに注目する必要があります。この方法を使用すると、識別データに依存したり、スレッド リストをステップ実行する必要はありません。

サンプル アプリケーションについては、以下の点に注意してください。

• スレッド識別データは、以下の 2 つの方法で作成されます。
  • 親スレッドでは、データは初期化されていない状態で作成されます。そして、スレッドは iddata ポインターを取得し、割り当て済みのメモリの領域を初期化します。
  • 子スレッドでは、アプリケーションによる iddata の割り当てと初期化が同時に実行される可能性を排除するために、初期化済みのデータを提供します。

  アプリケーションで使用する方法は、識別データの競合がどの程度予測されるかによります。

• 子スレッドがスレッド識別データを作成するのを待つ親スレッドでのループと、親スレッドが終了フラグを設定するのを待つ子スレッドでのループにも注目してください。CBL_THREAD_YIELD を呼び出すと、これらのループがハードウェアのビジー状態で待機するのを回避できますが、イベント同期オブジェクト、条件同期オブジェクト、または CBL_THREAD_SUSPEND と CBL_THREAD_RESUME を使用してコードを作成することをお奨めします。非マネージ コードでは、CBL_THREAD_SUSPEND と CBL_THREAD_RESUME を交互に使用できます。
• この API により、スレッドは、ランタイム システムで認識されているすべてのスレッドをステップ実行し、スレッド ハンドル、スレッド状態、識別データ ポインターを取得できます。この例では、ハンドルおよび識別データ ポインターのみを使用しています。ただし対象のスレッドが、デタッチされたスレッド、中断されたスレッド、または他言語のスレッドであるかどうかを呼び出しスレッドに通知することができる点で、状態情報も便利です。

  スレッドが CBL_THREAD_LIST ルーチンを使用した場合:

  • そのスレッドは、使用できる他の CBL_THREAD_n ルーチンが限定されます
  • 他のスレッドは、CBL_THREAD_n ルーチンを使用できず、他のライブラリ ルーチンの使用は制限されます

  そのため、以下のことを実行するべきです。

  • リストのステップ中に実行されるコードの量を最小限に抑えます
  • リストのロック中はファイルまたはユーザー I/O を避けます

  この制限は、CBL_THREAD_LIST_END 呼び出しによりステップ実行が終了すると、すぐに解除されます。