動的 SQL

DB2

第 7 章 OpenESQL

OpenESQL は、COBOL アプリケーションで埋め込み SQL を使用し、ODBC 対応のデータソースにアクセスするための統合型プリプロセッサです。

個別のプリプロセッサとは異なり、OpenEQL は、アプリケーションのコンパイル時に、SQL 指令を指定することによって制御します。

7.1 ODBC ドライバとデータベースクライアントソフトウェア

OpenESQL を使用するプログラムは、実行時に ODBC ドライバを使用して、リレーショナルデータベースにアクセスします。 ODBCドライバ製品は Server Express とは別に購入してください。

7.1.1 Oracle OCI サポート

Oracle データベースを使用しており、SQL (TARGETDB=ORACLEOCI) 指令でコンパイルする場合は、アプリケーションが実行時に ODBC 呼び出しではなく、OCI 呼び出しを行います。これは、配備されたアプリケーションが、潜在的なコストとパフォーマンスの利点を有する ODBC ドライバを必要としないことを意味します。

Oracle OCI を使用する場合は、次に示す OpenESQL 機能がサポートされていないことを知っておく必要があります。

• BEGIN TRANSACTION 文
• CALL 文
• EXECSP 文
• QUERY ODBC 文
• SET AUTOCOMMIT 文
• SET TRANSACTION ISOLATION 文
• カーソルのスクロール (SET SCROLLOPTION および SET CONCURRENCY 文を含む)
• CONNECT 文での WITH PROMPT パラメータ(UNIX では利用できません)
• SQL (CONNECTIONPOOL) 指令

Oracle OCI を使用する場合は、ODBC データソース名が適用されないため、CONNECT 文は実際の ORACLE データベースを参照します。

7.2 SQL コンパイラ指令

埋め込み SQL 文を含むプログラムをコンパイルする場合は、コンパイラ指令 SQL と適切なオプションを指定する必要があります。プログラムから呼び出す ODBC ドライバは、アクセスするデータソースによって決定されます。

他のコンパイラ指令を指定できる個所ならどこでも、SQL 指令を指定することができます。つまり、次の場所に指定できます。

• $SET 文の中。たとえば、次のように指定します。

  $set sql(dbman=odbc, autocommit) 

• cob コマンドライン上。たとえば、次のように指定します。

  cob -V testconn.cbl -C"anim SQL(DBMAN=ODBC)"

• COBOL.DIR ファイルの中。

備考：上記の 3 つの方法を併用することはできません。いずれかの方法のみを使用してください。

SQL コンパイラ指令オプションについて、以下に説明します。

7.3 デバッグファイルの生成

プログラムのコンパイル時に、技術的なサポートを要するエラーが発生した場合、サポート担当者から、問題の原因特定のためにデバッグファイルの提供を依頼されることがあります。こうしたデバッグファイルは、専用の SQL コンパイラ指令を指定して取得します。独自にデバッグ作業を行う場合にもこれらの指令が役立ちます。次の指令があります。

7.4 データベース接続

プログラムからデータベース内のデータにアクセスするには、その前に対象データベースへの接続を確立する必要があります。

プログラムは、次の 2 通りの方法でデータベースに接続できます。

• CONNECT 文による接続（通常はこの方法を使用してください。）

  次のいずれかにあてはまる場合は、一般的に CONNET 文が使用されます。

  • コンパイル時には名前が判明しないさまざまなデータソースにアクセスするようにプログラムが設計されている。

  • プログラムが複数のデータベースにアクセスする。

• 自動接続

  通常、コンパイル時に指定したデータベースのみにアクセスするプログラムに使用します。SQL コンパイラ 指令の INIT オプションを指定すると、SQL コンパイラの DB オプションで指定されたデータソースに PASS オプションで指定されたログイン情報を使用して自動接続するコードが、コンパイラによってプログラムの開始部分に挿入されます。

アプリケーションによるデータベース操作が完了すると、データベースとの接続を解除する必要があります。この処理には DISCONNECT 文を使用します。

自動接続を使用している場合には、プログラムの終了時に OpenESQL によってデータソースとの接続が自動的に解除されます。

プログラムの異常終了時に、OpenESQL に接続の解除とロールバックを自動実行させるには、SQL コンパイラ 指令の INIT=PROT オプションを指定します。

7.5 キーワード

OpenESQL では数多くのキーワードが予約されています。該当する単語は、プログラム内で他の用途に使用すべきではありません。予約済みキーワードのリストは、付録 『予約済みキーワード』に記載されています。

7.6 アプリケーションのビルド

OpenESQL アプリケーションの作成に必要な手順は、次のとおりです。

1. アプリケーションをコーディングします。Micro Focus Net Express も使用している場合は、パーソナルコンピュータで OpenESQL Assistant を使用してアプリケーションを開発し、それを UNIX システムで公開するほうが簡単であることがわかります。Net Express OpenESQL Assistant では、SQL 文の開発にグラフィカルなドラッグアンドドロップの方法を提供しています。

2. SQL 指令と適切なオプションの指定を確実に行い、アプリケーションをコンパイルします。少なくとも SQL を指定します。

3. ODBC データソースを設定します。方法についてはお使いの ODBCドライバのドキュメントを参照してください。

コピーファイル、sqlca.cpy と sqlda.cpy は、$COBDIR/cpylib ディレクトリに提供されます。このディレクトリが COBCPY 環境変数に確実に設定されるようにする必要があります。

7.7 デモンストレーション アプリケーション

Server Express をインストールすると、openesql ディレクトリにさまざまなデモンストレーション アプリケーションがコピーされます。openesql ディレクトリは、Server Express のインストール ディレクトリの demo サブディレクトリ内に生成されています。

デモンストレーション アプリケーションを使用するには、1 つ以上の ODBC ドライバをインストールしておく必要があります。

デモンストレーションアプリケーションの中には、接続しているデータベースに EMP という表を要求するものもあります。

OpenESQL を使用するデモンストレーション アプリケーションを次に示します。これらのアプリケーションは、いずれかも処理の進行状況をコンソールに表示し、照会結果を表示する場合もあります。処理中にエラーが発生すると、エラー メッセージを表示して終了します。

次のプログラムが提供されます。

• testconn.cbl

  testconn.cbl ファイルは、CONNECT 文と DISCONNECT 文のさまざまなフォーマットの使用方法を示す OpenESQL のデモンストレーションプログラムです。

• catalog.cbl

  catalog.cbl ファイルは、COBOL からの ODBC カタログ機能の使いかたを示す OpenESQL のデモンストレーションプログラムです。

• static.cbl

  static.cbl ファイルは、COBOL からの 基本的な SQL 機能の使いかたを示す OpenESQL のデモンストレーションプログラムです。INSERT、UPDATE、DELETE、SELECT INTO および カーソルを使用したSELECT の使いかたの例を解説しています。また、COMMIT および ROLLBACK の使いかたも示しています。

• dynquery.cbl

  dynquery.cbl は 、COBOL からの 動的 SQL 機能の使いかたを示す OpenESQL のデモンストレーションプログラムです。 ユーザが何らかの SQL 文を入力し、プログラムがそれらを実行する機能を提供しています。SQL 文を用意する方法を示し、プログラムのコンパイル時に列のタイプがわからない場合に、SQLDA 構造体を使用して、列からデータを取り出す方法を示します。

  上記で説明した EMP 表にアクセスしている場合、サンプルのクエリーは次のようなものになります。

  select FIRST_NAME, LAST_NAME, HIRE_DATE, SALARY from EMP

7.8 トランザクション管理

OpenESQL では、COMMIT 文と ROLLBACK 文によって ODBC のトランザクション管理機能を制御できます。ODBC では、各ステートメントの実行後にトランザクションが標準で自動コミットされますが、OpenESQL では他の SQL システムとの互換性を考慮して、この機能は無効化されています。自動コミットを有効化するには、SQL コンパイラ 指令の AUTOCOMMIT オプションを指定してください。

注: すべての ODBC ドライバがトランザクション処理を実装しているとはかぎりません。 トランザクション処理を実装していないドライバは、データベースへの即時的で永続的な更新を行います。

7.9 データ型

以下の表は、SQL と COBOL 間でデータ型を変換するときに、OpenESQL が用いるマッピングを示したものです。

ODBC では、日付が yyyy-mm-dd、時刻が hh:mm:ss の形式で表記されます。これらの形式は、データソース側の日付や時刻の表記形式と一致しない可能性があります。入力文字ホスト変数には、データソース側の形式を使用できます。ほとんどのデータソースでは PIC X(29) を使用してください。次に例を示します。

01  mydate      PIC x(29).
...
EXEC SQL
   INSERT INTO TABLE1 VALUES (1,'1997-01-24 12:24')
END-EXEC
...
EXEC SQL
   SELECT DT INTO :mydate FROM TABLE1 WHERE X = 1
END-EXEC
DISPLAY mydate

ODBC のエスケープ シーケンスを使用することも可能です。ODBC では、日付、時刻、およびタイムスタンプの各リテラル用のエスケープ シーケンスが定義されています。これらのエスケープ シーケンスは、ODBC ドライバによってデータソース側の構文に変換されます。

エスケープ シーケンスによる日付、時刻、およびタイムスタンプの各リテラルの表記方法は次のとおりです。

{d 'yyyy-mm-dd'} - for date.
{t 'hh:mm:ss'} - for time.
{ts yyyy-mm-dd hh:mm:ss[.f...] - for timestamp.

以下のサンプルプログラムでは、使用される日付、時間およびタイムスタンプのエスケープシーケンスを示しています。

 working-storage section.
 EXEC SQL INCLUDE SQLCA END-EXEC

 01  date-field1      pic x(29).
 01  date-field2      pic x(29).
 01  date-field3      pic x(29).

 procedure division.
* データソースへの接続。これは、Server Express に
* 提供されるサンプルのデータソースの 1 つです。
     EXEC SQL
         CONNECT TO 'Server Express Sample1' USER 'admin'
     END-EXEC
* テーブルが存在する場合は、それを削除します。
     EXEC SQL
         DROP TABLE DT
     END-EXEC

* DATE、TIME、DATE および TIME の列を持つテーブルを作成します。 
* 
* 注:   3 つのすべての列について、アクセスは DATETIME 列を使用します。
*      専用の列タイプを持つデータベースもあります。
* 他のデータソースで DATE/TIME 列を作成している場合は、
* データベースのドキュメントを参照して、
* 列の定義方法を調べてください。

     EXEC SQL
         CREATE TABLE DT ( id  INT,
                           myDate DATE NULL,
                           myTime TIME NULL,
                           myTimestamp TIMESTAMP NULL)
     END-EXEC

* ODBC エスケープシーケンスを使用して、テーブルに値を挿入します。

     EXEC SQL
         INSERT into DT values (1 ,
               {d '1961-10-08'},  *> Set just the date part
               {t '12:21:54'  },  *> Set just the time part
               {ts '1966-01-24 08:21:56' } *> Set both parts
                   )
     END-EXEC

* 挿入した値を取り出します。
   
     EXEC SQL
         SELECT myDate
               ,myTime
               ,myTimestamp
           INTO
                :date-field1
               ,:date-field2
               ,:date-field3
           FROM DT
           where id = 1
     END-EXEC

* 結果を表示します。

     display 'where the date part has been set :' 
             date-field1
     display 'where the time part has been set :' 
             date-field2
     display 'NOTE, most data sources will set a default'
             ' for the date part '
     display 'where both parts has been set :' 
             date-field3

* テーブルを削除します。
   
     EXEC SQL
         DROP TABLE DT
     END-EXEC

* データソースから切断します。

     EXEC SQL
         DISCONNECT CURRENT
     END-EXEC

     stop run.

01  my-id          pic s9(09) comp-5
01  my-date        sql type is date
01  my-time        sql type is time
01  my-timestamp   sql-type is timestamp

* SQL TYPEホスト変数を使ったINSERT文
     MOVE 1                           TO  my-id
     MOVE "1961-10-08"                TO  my-date
     MOVE "12:21:54"                  TO  my-time
     MOVE "1966-01-24 08:21:56"       TO  my-timestamp
 
     EXEC SQL
        INSERT into DT vlaue (
           :my-id
          ,:my-date
          ,:my-time
          ,:my-timestamp  )
     END-EXEC

7.10 SQLCA の使用

SQLCA データ構造体は、Server Express インストール ディレクトリの cpylib サブディレクトリ内の sqlca.cpy ファイルで定義されています。SQLCA をプログラムで使用するには、Data Division に次の文を記述します。

EXEC SQL INCLUDE SQLCA END-EXEC

この文を記述しない場合でも、COBOL コンパイラによって自動的に領域が割り当てられますが、プログラムはその領域にはアクセスできません。ただし、sqlcode （または sqlstate）データ項目を別に宣言すれば、各 SQL EXEC 文の実行後に SQLCA 内の対応フィールドをユーザ定義フィールドにコピーするコードが COBOL コンパイラによって生成されます。

MFSQLMESSAGETEXT データ項目を宣言した場合には、sqlcode にゼロ以外の値が検出されるたびに、例外条件の説明によって同データ項目が更新されます。MFSQLMESSAGETEXT は文字データ項目 PIC X(n) として宣言します（n は任意の有効値）。ODBC エラー メッセージは、SQLCA メッセージ フィールドのサイズ（70 バイト）を超過することが少なくありません。そのため、MFSQLMESSAGETEXT データ項目はとくに有効です。

備考：SQLCA や SQLCODE、SQLSTATE、および MFSQLMESSAGETEXT は、いずれもホスト変数として宣言する必要はありません。

7.11 ストアド プロシージャ

OpenESQL では、2 つの文（CALL および EXECSP）をストアド プロシージャと組み合わせて使用できます。

• CALL

  CALL は、ODBC ストアド プロシージャの呼び出しに使用します。

• EXECSP

  Microsoft SQL Server 対応 Micro Focus Embedded SQL Toolkit との後方互換を提供します。

ストアド プロシージャでは次の処理を実行できます。

• 引数の入力
• 引数による値の戻し
• 引数の入力と引数による値の戻し
• 位置型引数やキーワード型引数の使用
• 結果の戻し
• 結果セットの戻し
• 引数配列による呼び出し

備考：ストアド プロシージャの機能はデータベース製品ごとに大きく異なり、各製品は上記の機能を部分的に実装しているに過ぎません。したがって、異なるデータベース製品間でのストアド プロシージャ呼び出しの移植性は、OpenESQL 文に比べると大幅に限定されます。

ストアド プロシージャの呼び出し時には、コンマ（,）で区切られた一連の引数が渡されます。（各引数はかっこで囲まれる場合もあります。） 引数にはホスト変数やリテラル、および CURSOR キーワードが使用できます。なお、CURSOR で渡された引数はバインドが解除されるため、結果セットを戻す Oracle 8 ストアド プロシージャ以外には使用すべきではありません。

引数としてホスト変数を渡す場合には、その後に引数の種類（IN、INPUT、INOUT、OUT、OUTPUT）を指定できます。種類のデフォルト値は INPUT です。

ホスト変数は、直前に正規のパラメータ名と等号（=）を指定することによって、キーワード型引数として渡すことも可能です。次に例を示します。

EXEC SQL CALL myProc (keyWordParam = :hostVar) END-EXEC

ポータビリティを最大限にするには、次のように行います。

• リテラルなパラメータの使用を避ける。

• ホスト変数のパラメータだけを使用する。

• 所定の呼び出しは、正規、ポジションあるいはキーワードのいずれかのパラメータを使用し、これらを混合しないようにします。これらのパラメータの混合をサポートするサーバもありますが、キーワードパラメータはポジションパラメータの後に置く必要があります。キーワードパラメータは、読みやすさという点で有用であり、サーバがデフォルトのパラメータ値とオプションのパラメータをサポートしている場合にも役に立ちます。

結果セットを戻すストアド プロシージャ呼び出しは、カーソル宣言で使用してください。次に例を示します。

EXEC SQL DECLARE cursorName CURSOR FOR storedProcecureCall

この場合、ストアド プロシージャは他のタイプのカーソルと同様に、カーソルの OPEN 処理と結果セット行の FETCH 処理によって呼び出されます。

現バージョンの OpenESQL は、複数の結果セットには対応していません。

ODBC パラメータは Oracleの配列引数とは異なります。配列引数を使用すれば、配列の各要素に同じ文を繰り返し実行した場合と同じ結果が得られます。ストアド プロシージャ呼び出しで 1 つの引数を配列として渡すと、その他のすべての引数も同じ数の要素を含む配列として渡す必要があります。ストアド プロシージャでは、これらの引数の各要素ごとに呼び出された場合と同様の処理が実行されます。引数で渡す要素数は、呼び出しの直前に FOR :hvar を指定することによって、配列の上限サイズを超えない数に制限することができます。ここで、:hvar は渡すべき要素の数を含む整数型のホスト変数です。

7.12 位置付け更新

ODBC は、カーソルを使用して直近にフェッチされた行を更新する、位置付け更新をサポートしています。ですが、すべてのドライバが位置付け更新をサポートしているとは限りません。

注: ホスト変数と位置付け更新を併用することはできません。

ODBC ドライバの中には、カーソルに使用される選択文の中に位置付け更新を可能にする FOR UPDATE 句が必要なドライバもあります。ほとんどのデータソースは、SET 文によって、あるいは DECLARE CURSOR 文の中に、CROLLOPTION と CONCURRENCY の組み合わせを指定する必要があります。これが正しく指定されていないと、ODBC Cursor Library は、SQL(USECURLIB=YES) 指令でコンパイルし、SCROLLOPTION STATIC および CONCURRENCY OPTCCVAL (または OPTIMISTIC) を使用して、位置付け更新の実装を制限します。ODBC Cursor Library を使用している場合に、複数の行が更新されるのを防ぐには、更新されるテーブルの主キー列(preimary key column)をカーソルクエリーにインクルードしてください。

例

$SET SQL(usecurlib=yes)
  WORKING-STORAGE SECTION.
 
  EXEC SQL INCLUDE SQLCA  END-EXEC
 
  *> SQL エラーの後では、ここはメッセージ文全体となります。
  01 MFSQLMESSAGETEXT  PIC X(250).
  01 IDX               PIC X(04)  COMP-5.

  EXEC SQL BEGIN DECLARE SECTION  END-EXEC
  *> 別の COBOL コンパイラにポートする必要がある場合は、
  *> 使用しているホスト変数をここに指定します。
  EXEC SQL INCLUDE Products END-EXEC
 
  EXEC SQL END DECLARE SECTION END-EXEC
 
  PROCEDURE DIVISION.
 
  EXEC SQL
      WHENEVER SQLERROR perform OpenESQL-Error
  END-EXEC
          
  *> ACCESS データソースを使用している位置付け更新の例題。   
  EXEC SQL
    CONNECT TO 'Inventory' USER 'admin'
  END-EXEC
 
  *> 使用しているプログラムロジック/SQL 文をここに指定します。
 
      EXEC SQL
       DECLARE CSR679 CURSOR
         FOR SELECT
              A.ProductID
             ,A.ProductName
             ,A.UnitPrice
         FROM Products A
        WHERE ( A.ProductID <  3 )
      END-EXEC
 
     EXEC SQL SET SCROLLOPTION static  END-EXEC
     EXEC SQL SET CONCURRENCY optccval END-EXEC
 
      EXEC SQL OPEN CSR679 END-EXEC
      PERFORM UNTIL SQLSTATE >= "02000"
        EXEC SQL
        FETCH CSR679 INTO
            :ProductID
           ,:ProductName:ProductName-NULL
           ,:UnitPrice:UnitPrice-NULL
        END-EXEC
        *> FETCH からのデータを処理します。 
        IF SQLSTATE = "00000"
           *> 価格を 10% 上げます。
            compute unitprice = unitprice * 1.10
            EXEC SQL
               UPDATE Products
                 SET UnitPrice = :UnitPrice:UnitPrice-NULL
               WHERE CURRENT OF CSR679
           END-EXEC
        END-IF
      END-PERFORM
      EXEC SQL CLOSE CSR679 END-EXEC
 
     EXEC SQL COMMIT END-EXEC
 
  EXEC SQL DISCONNECT CURRENT END-EXEC
  EXIT PROGRAM.
  STOP RUN.
  *> デフォルトの SQL エラールーチン / 必要に応じてプログラムを停止するように変更します。
  OpenESQL-Error Section.
 
      display "SQL Error = " sqlstate " " sqlcode
      display MFSQLMESSAGETEXT
  *> 実行を停止します。
      exit.

7.13 OpenESQLでのUnicodeサポート

アプリケーションの中には、Microsoft SQL Server のデータソースを ANSI に変換せずに取り出したり、格納したりするものがあります。OpenESQL の以前のバージョンでは、データが自動的に変換されていないと、データにアクセスする手段はありませんでした。しかし、現在のバージョンでは、OpenESQL と Server Express は、ANSI に変換されていなくても、新しいタイプのホスト変数を使用することで、ユニコードのデータに直接アクセスできます。Microsoft SQL Server は、次の 3 つのタイプのUnicode列をサポートしています。

• NCHAR
• NVARCHAR
• NTEXT

自動的にデータを変換せずにこうした列にアクセスするには、次のようにホスト変数を定義します。

PIC N(xx) USAGE NATIONAL

ここで、xx は、列のサイズです。現在のバージョンでは、この形式は、固定長データと可変長データの両方をサポートしています。可変長データは、データの挿入あるいは更新の際に、列に対するデータの最後であることを示すヌルで終了します。データがソースデータから取り出されると、ホスト変数の最後までスペースが充填されます。

例えば、次のプログラムは、Microsoft SQL Server 2000 を搭載している Northwind のサンプルデータベースから従業員情報を取り出します。

       $SET UNICODE(NATIVE)
       $SET SQL
       WORKING-STORAGE SECTION.

       EXEC SQL INCLUDE SQLCA  END-EXEC

       *>  SQL エラーの後では、ここはメッセージ文全体となります。
       01 MFSQLMESSAGETEXT  PIC X(250).
       01 IDX               PIC X(04)  COMP-5.

       EXEC SQL BEGIN DECLARE SECTION  END-EXEC
       *> 別の COBOL コンパイラにポートする必要がある場合は、
  　　 *> 使用しているホスト変数をここに指定します。
       EXEC SQL INCLUDE Employees END-EXEC

       EXEC SQL END DECLARE SECTION END-EXEC

       PROCEDURE DIVISION.

       EXEC SQL
           WHENEVER SQLERROR perform OpenESQL-Error
       END-EXEC

       EXEC SQL
         CONNECT TO 'LocalServer'
       END-EXEC

       *> 使用しているプログラムロジック/SQL 文をここに指定します。
            EXEC SQL
             DECLARE CSR135 CURSOR FOR SELECT
                    A.FirstName
                   ,A.LastName
                   ,A.EmployeeID
                   ,A.HireDate
               FROM Employees A
            END-EXEC
            EXEC SQL OPEN CSR135 END-EXEC
            PERFORM UNTIL SQLSTATE >= "02000"
              EXEC SQL
              FETCH CSR135 INTO
                  :Employees-FirstName
                 ,:Employees-LastName
                 ,:Employees-EmployeeID
                 ,:Employees-HireDate:Employees-HireDate-NULL
              END-EXEC

              *> FETCH からのデータを処理します。 
              IF SQLSTATE < "02000"

              *> 配列フェッチの場合、sqlerrd(3) フィールドは、
              *> 返された行数となります。
              *>  PERFORM VARYING IDX FROM 1 BY 1 UNTIL IDX > SQLERRD(3)

              *>  配列を処理するにはここにコードを追加する必要があります。

              *>  END-PERFORM
               END-IF
            END-PERFORM
            EXEC SQL CLOSE CSR135 END-EXEC

       EXEC SQL DISCONNECT CURRENT END-EXEC
       EXIT PROGRAM.
       STOP RUN.
       *> デフォルトのSQL エラールーチン / 必要に応じてプログラムを停止します。
       OpenESQL-Error Section.

           display "SQL Error = " sqlstate " " sqlcode
           display MFSQLMESSAGETEXT
       *> 実行を停止します。
           exit.

これは、INCLUDE copybook Employees　の定義以外、ANSI のデータを取り出すのと同じコードです。INCLUDE copybook Employees は次のよう定義します。

      *>  --------------------------------------------------------------
      *> 従業員テーブルに対するCOBOL 宣言
      *>  --------------------------------------------------------------
       01  DCLEmployees.
           03 Employees-EmployeeID             PIC S9(09)  COMP-5.
           03 Employees-LastName               PIC N(20)
                                   USAGE NATIONAL.
           03 Employees-FirstName              PIC N(10)
                                   USAGE NATIONAL.
           03 Employees-Title                  PIC N(30)
                                   USAGE NATIONAL.
           03 Employees-TitleOfCourtesy        PIC N(25)
                                   USAGE NATIONAL.
           03 Employees-BirthDate              PIC X(23).
           03 Employees-HireDate               PIC X(23).
           03 Employees-Address                PIC N(60)
                                   USAGE NATIONAL.
           03 Employees-City                   PIC N(15)
                                   USAGE NATIONAL.
           03 Employees-Region                 PIC N(15)
                                   USAGE NATIONAL.
           03 Employees-PostalCode             PIC N(10)
                                   USAGE NATIONAL.
           03 Employees-Country                PIC N(15)
                                   USAGE NATIONAL.
           03 Employees-HomePhone              PIC N(24)
                                   USAGE NATIONAL.
           03 Employees-Extension              PIC N(4)
                                   USAGE NATIONAL.
           03 Employees-Photo                  PIC X(64000).
           03 Employees-Notes                  PIC N(32000)
                                   USAGE NATIONAL.
           03 Employees-ReportsTo              PIC S9(09)  COMP-5.
           03 Employees-PhotoPath              PIC N(255)
                                   USAGE NATIONAL.

動的 SQL

DB2